К основному контенту

Полезные штучки

Коллекция командных файлов (.cmd)


Очистка кэша иконок

clear_icon_cache.cmd

taskkill /f /im explorer.exe
cd /d %userprofile%\AppData\Local
attrib -h IconCache.db
del IconCache.db
%WINDIR%\explorer.exe

Очистка папки временных файлов

Clear_TEMP.cmd

pushd %TEMP% && rd /s /q . > nul 2>&1
pushd %TMP% && rd /s /q . > nul 2>&1

Запуск SOTA

sota.cmd

start /D"%userprofile%\AppData\Roaming\UniCryptH\" UniCryptH.exe
ping -n 2 -w 1000 127.0.0.1 > nul
start /D"D:\soft\GoogleChromePortable\" GoogleChromePortable.exe https://sota-buh.com.ua/

Автоматическое монтирование/размонтирование образа

mount_iso.cmd

start /MIN /D"c:\Program Files\DAEMON Tools Lite\" DTLite.exe -unmount_all
ping -n 5 -w 1000 127.0.0.1 > nul
start /MIN /D"c:\Program Files\DAEMON Tools Lite\" DTLite.exe -mount scsi, 0, d:\iso\iso-2-mount.iso

Объединение/разделение PDF, TIFF

menu61=-
menu62=Конвертировать в PDF
cmd62=%commander_path%\utils\IrfanView\i_view32.exe
param62=%P%N /convert=%P%O.pdf
menu63=Объединить PDF (макс. 50 файлов)
cmd63=%commander_path%\utils\helpers\concat_pdf.cmd
param63=%t %p%s50
path63=%commander_path%\utils\pdfsam\bin\
menu64=Разделить PDF по листам
cmd64=%commander_path%\utils\pdfsam\bin\run-console.bat
param64=-f %P%N -s BURST -o %t -compressed split
path64=%commander_path%\utils\pdfsam\bin\
menu65=Создать TIFF (макс. 50 файлов)
cmd65=%commander_path%\utils\helpers\concat_tiff.cmd
param65=%t %p%s50
menu66=Разделить TIFF по листам
cmd66=%commander_path%\utils\IrfanView\i_view32.exe
param66=%P%N /extract=(%t,%E) /cmdexit
menu67=--

concat_pdf.cmd

IF -%2==- GOTO :ERROR
IF -%3==- GOTO :ERROR
SET N=%1
SET S=-f %2 -f %3
:MOVEIT
SHIFT
IF -%3==- GOTO :STARTPDFSAM
SET S=%S% -f %3
GOTO :MOVEIT
:ERROR
@ECHO ----------------------------------------
@ECHO !!!!!            ERROR             !!!!!
@ECHO !!!                                  !!!
@ECHO !!      2 or more files required      !!
@ECHO !!                                    !!
@ECHO ----------------------------------------
@PAUSE
@GOTO :END
:STARTPDFSAM
SET CurrentDate=%date:~-4,4%-%date:~-7,2%-%date:~-10,2%
set Currenthour=%time: =0%
SET CurrentTime=%Currenthour:~-0,2%-%time:~-8,2%-%time:~-5,2%
%commander_path%\utils\pdfsam\bin\run-console.bat %S% -o %N%%CurrentDate%_%CurrentTime%_PDFsam_Concat.pdf concat
:END

concat_tiff.cmd

IF -%2==- GOTO :ERROR
IF -%3==- GOTO :ERROR
SET N=%1
SET S=%2,%3
:MOVEIT
SHIFT
IF -%3==- GOTO :STARTIRFAN
SET S=%S%,%3
GOTO :MOVEIT
:ERROR
@ECHO ----------------------------------------
@ECHO !!!!!            ERROR             !!!!!
@ECHO !!!                                  !!!
@ECHO !!      2 or more files required      !!
@ECHO !!                                    !!
@ECHO ----------------------------------------
@PAUSE
@GOTO :END
:STARTIRFAN
SET CurrentDate=%date:~-4,4%-%date:~-7,2%-%date:~-10,2%
set Currenthour=%time: =0%
SET CurrentTime=%Currenthour:~-0,2%-%time:~-8,2%-%time:~-5,2%
%commander_path%\utils\irfanview\i_view32.exe /multitif=(%N%%CurrentDate%_%CurrentTime%_IrfanView_Concat.tif,%S%) /tifc=7 /cmdexit
:END

Создание папки с именем текущей даты (YYYY-MM-DD)

CreateDateDir.cmd

SET CurrentDate=%date:~-4,4%-%date:~-7,2%-%date:~-10,2%
md %1\%CurrentDate%

Создание папки с именем текущей даты/времени (YYYY-MM-DD_HH-MM-SS)

CreateDateTimeDir.cmd

SET CurrentDate=%date:~-4,4%-%date:~-7,2%-%date:~-10,2%
set Currenthour=%time: =0%
SET CurrentTime=%Currenthour:~-0,2%-%time:~-8,2%-%time:~-5,2%
md %1\%CurrentDate%_%CurrentTime%

Динамическое подключение сетевых дисков

ConnectNetworkDrivesSOK.cmd

ping -n 1 -w 500 192.168.1.8
if not errorlevel 1 net use r: \\192.168.1.8\vv "pass word" /USER:Quest /persistent:no
ping -n 1 -w 500 192.168.1.6
if not errorlevel 1 net use o: \\192.168.1.6\buh "p@ssword" /USER:KB /persistent:no
ping -n 1 -w 500 192.168.1.11
if not errorlevel 1 net use k: \\192.168.1.11\vk "15pass#word" /USER:Quest /persistent:no
ping -n 1 -w 500 192.168.1.3
if not errorlevel 1 net use s: \\192.168.1.3\glavbuh "17 pas sword" /USER:Admin /persistent:no

Архивация папки Документы

Archive_mydoc.bat

SET CurrentDate=%date:~-4,4%%date:~-7,2%%date:~-10,2%
set Currenthour=%time: =0%
SET CurrentTime=%Currenthour:~-0,2%%time:~-8,2%%time:~-5,2%
"d:\mzy\MzYpORtAbLeSuiTe\utils\7zip\App\7-Zip64\7z.exe" a d:\backup\temp1.7z -ssw -y -wd:\backup\ -r "d:\Документы\" -x!*.mp3 -x!*.avi -x!*.wma -x!*.wav -mx -mmt=on >> backup_log.%date%.txt
ren "d:\backup\temp1.7z" "backup_mydoc_%CurrentDate%_%CurrentTime%.7z"

Архивация на сетевой диск

Archive_2_netO.bat

SET CurrentDate=%date:~-4,4%%date:~-7,2%%date:~-10,2%
set Currenthour=%time: =0%
SET CurrentTime=%Currenthour:~-0,2%%time:~-8,2%%time:~-5,2%
ping -n 1 -w 500 192.168.1.6
if not errorlevel 1 net use o: \\192.168.1.6\buh "p@ssword" /USER:Guest /persistent:no
"c:\Soft\MzYpORtAbLeSuiTe\utils\7zip\App\7-Zip64\7z.exe" a o:\backup\temp1.7z -ssw -y -wo:\backup\ -r "c:\Users\хаха\Documents\*.*" -x!*.mp3 -x!*.avi -x!*.wma -x!*.wav -mx -mmt=on >> backup_log.%date%.txt
ren "o:\backup\temp1.7z" "glbuh_doc_%CurrentDate%_%CurrentTime%.7z"
"c:\Soft\MzYpORtAbLeSuiTe\utils\7zip\App\7-Zip64\7z.exe" a o:\backup\temp1.7z -ssw -y -wo:\backup\ -r "c:\Users\хаха\Desktop\*.*" -x!*.mp3 -x!*.avi -x!*.wma -x!*.wav -mx -mmt=on >> backup_log.%date%.txt
ren "o:\backup\temp1.7z" "glbuh_desk_%CurrentDate%_%CurrentTime%.7z"
"c:\Soft\MzYpORtAbLeSuiTe\utils\7zip\App\7-Zip64\7z.exe" a o:\backup\temp1.7z -ssw -y -wo:\backup\ -r "c:\opz" -x!*.mp3 -x!*.avi -x!*.wma -x!*.wav -mx -mmt=on >> backup_log.%date%.txt
ren "o:\backup\temp1.7z" "glbuh_opz_%CurrentDate%_%CurrentTime%.7z"

Интеграция AES-шифрования с помощью openssl

MzYeasyWay2.cmd

set sslpath="c:\soft\MzYpORtAbLeSuiTe\utils\openssl\OpenSSL-Win64\bin\openssl.exe"
set z7path="c:\soft\MzYpORtAbLeSuiTe\utils\7zip\App\7-Zip64\7z.exe"
rem helperpath=c:\\soft\\MzYpORtAbLeSuiTe\\utils\\openssl\\helpers\\ - without quotes, in "regedit" format
set helperpath=c:\\soft\\MzYpORtAbLeSuiTe\\utils\\openssl\\helpers\\
rem arctype=sevenzip or zip
set arctype=sevenzip

if %arctype%==sevenzip goto sevenzip

set zipcomment=0
set sevcomment=;;

(echo.@ECHO OFF
echo.rem  Based on Convenient Encryption by Scott D. Stoller
echo.rem  Adapted by MzY
echo.rem  This program is free software: you can redistribute it and/or modify
echo.rem  it under the terms of the GNU General Public License as published by
echo.rem  the Free Software Foundation, either version 3 of the License, or
echo.rem  [at your option] any later version.
echo.rem  This program is distributed in the hope that it will be useful,
echo.rem  but WITHOUT ANY WARRANTY; without even the implied warranty of
echo.rem  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
echo.rem  GNU General Public License for more details.
echo.rem  You should have received a copy of the GNU General Public License
echo.rem  along with this program.  If not, see http://www.gnu.org/licenses/.
echo.rem set working directory to the directory containing the target file
echo.cd %%~p1
echo.set targetzipaes=%%~1
echo.set extension=%%targetzipaes:~-8,8%%
echo.set targetzip=%%targetzipaes:~0,-4%%
echo.set target=%%targetzipaes:~0,-8%%
echo.if not %%extension%%==.zip.aes goto wrongextension
echo.if exist "%%targetzip%%" goto zipexists
echo.if exist "%%target%%" goto targetexist
echo.if not exist %z7path% goto 7zanotexist
echo.if not exist %sslpath% goto opensslnotexist
echo.%sslpath% enc -d -aes-256-cbc -in "%%targetzipaes%%" -out "%%targetzip%%"
echo.%z7path% x "%%targetzip%%"
echo.del "%%targetzip%%"
echo.PAUSE
echo.EXIT
echo.
echo.:wrongextension
echo.echo Error: target filename does not end with .zip.aes
echo.PAUSE
echo.EXIT
echo.
echo.:zipexists
echo.echo Error: %%targetzip%% already exists.  Delete it and re-try.
echo.PAUSE
echo.EXIT
echo.
echo.:targetexist
echo.echo Error: %%target%% already exists.  Delete it and re-try.
echo.PAUSE
echo.EXIT
echo.
echo.:7zanotexist
echo.ECHO Error: %z7path% does not exist.
echo.PAUSE
echo.EXIT
echo.
echo.:opensslnotexist
echo.ECHO Error: %sslpath% does not exist.
echo.PAUSE
echo.EXIT)>decryptAndUnzip.cmd

(echo.@ECHO OFF
echo.rem  Based on Convenient Encryption by Scott D. Stoller
echo.rem  Adapted by MzY
echo.rem  This program is free software: you can redistribute it and/or modify
echo.rem  it under the terms of the GNU General Public License as published by
echo.rem  the Free Software Foundation, either version 3 of the License, or
echo.rem  [at your option] any later version.
echo.rem  This program is distributed in the hope that it will be useful,
echo.rem  but WITHOUT ANY WARRANTY; without even the implied warranty of
echo.rem  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
echo.rem  GNU General Public License for more details.
echo.rem  You should have received a copy of the GNU General Public License
echo.rem  along with this program.  If not, see http://www.gnu.org/licenses/.
echo.rem set working directory to the directory containing the target folder
echo.cd %%1
echo.cd ..
echo.set target=%%~n1
echo.set targetzip=%%target%%.zip
echo.set targetzipaes=%%target%%.zip.aes
echo.if exist %%targetzip%% goto zipexists
echo.if exist %%targetzipaes%% goto zipaesexists
echo.if not exist %z7path% goto 7zanotexist
echo.if not exist %sslpath% goto opensslnotexist
echo.%z7path% a "%%targetzip%%" "%%target%%" -r
echo.%sslpath% enc -e -aes-256-cbc -in "%%targetzip%%" -out "%%targetzipaes%%"
echo.del "%%targetzip%%"
echo.PAUSE
echo.EXIT
echo.
echo.:zipexists
echo.ECHO Error: %%targetzip%% already exists.  Delete it and re-try.
echo.PAUSE
echo.EXIT
echo.
echo.:zipaesexists
echo.ECHO Error: %%targetzipaes%% already exists.  Delete it and re-try.
echo.PAUSE
echo.EXIT
echo.
echo.:7zanotexist
echo.ECHO Error: %z7path% does not exist.
echo.PAUSE
echo.EXIT
echo.
echo.:opensslnotexist
echo.ECHO Error: %sslpath% does not exist.
echo.PAUSE
echo.EXIT)>zipAndEncrypt.cmd

goto commonpart

:sevenzip

set zipcomment=;;
set sevcomment=0

(echo.@ECHO OFF
echo.rem  Based on Convenient Encryption by Scott D. Stoller
echo.rem  Adapted by MzY
echo.rem  This program is free software: you can redistribute it and/or modify
echo.rem  it under the terms of the GNU General Public License as published by
echo.rem  the Free Software Foundation, either version 3 of the License, or
echo.rem  [at your option] any later version.
echo.rem  This program is distributed in the hope that it will be useful,
echo.rem  but WITHOUT ANY WARRANTY; without even the implied warranty of
echo.rem  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
echo.rem  GNU General Public License for more details.
echo.rem  You should have received a copy of the GNU General Public License
echo.rem  along with this program.  If not, see http://www.gnu.org/licenses/.
echo.rem set working directory to the directory containing the target file
echo.cd %%~p1
echo.set targetzipaes=%%~1
echo.set extension=%%targetzipaes:~-7,7%%
echo.set targetzip=%%targetzipaes:~0,-4%%
echo.set target=%%targetzipaes:~0,-7%%
echo.if not %%extension%%==.7z.aes goto wrongextension
echo.if exist "%%targetzip%%" goto zipexists
echo.if exist "%%target%%" goto targetexist
echo.if not exist %z7path% goto 7zanotexist
echo.if not exist %sslpath% goto opensslnotexist
echo.%sslpath% enc -d -aes-256-cbc -in "%%targetzipaes%%" -out "%%targetzip%%"
echo.%z7path% x "%%targetzip%%"
echo.del "%%targetzip%%"
echo.PAUSE
echo.EXIT
echo.
echo.:wrongextension
echo.echo Error: target filename does not end with .zip.aes
echo.PAUSE
echo.EXIT
echo.
echo.:zipexists
echo.echo Error: %%targetzip%% already exists.  Delete it and re-try.
echo.PAUSE
echo.EXIT
echo.
echo.:targetexist
echo.echo Error: %%target%% already exists.  Delete it and re-try.
echo.PAUSE
echo.EXIT
echo.
echo.:7zanotexist
echo.ECHO Error: %z7path% does not exist.
echo.PAUSE
echo.EXIT
echo.
echo.:opensslnotexist
echo.ECHO Error: %sslpath% does not exist.
echo.PAUSE
echo.EXIT)>decryptAndUnpack7z.cmd

(echo.@ECHO OFF
echo.rem  Based on Convenient Encryption by Scott D. Stoller
echo.rem  Adapted by MzY
echo.rem  This program is free software: you can redistribute it and/or modify
echo.rem  it under the terms of the GNU General Public License as published by
echo.rem  the Free Software Foundation, either version 3 of the License, or
echo.rem  [at your option] any later version.
echo.rem  This program is distributed in the hope that it will be useful,
echo.rem  but WITHOUT ANY WARRANTY; without even the implied warranty of
echo.rem  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
echo.rem  GNU General Public License for more details.
echo.rem  You should have received a copy of the GNU General Public License
echo.rem  along with this program.  If not, see http://www.gnu.org/licenses/.
echo.rem set working directory to the directory containing the target folder
echo.cd %%1
echo.cd ..
echo.set target=%%~n1
echo.set targetzip=%%target%%.7z
echo.set targetzipaes=%%target%%.7z.aes
echo.if exist %%targetzip%% goto zipexists
echo.if exist %%targetzipaes%% goto zipaesexists
echo.if not exist %z7path% goto 7zanotexist
echo.if not exist %sslpath% goto opensslnotexist
echo.%z7path% a "%%targetzip%%" "%%target%%" -r
echo.%sslpath% enc -e -aes-256-cbc -in "%%targetzip%%" -out "%%targetzipaes%%"
echo.del "%%targetzip%%"
echo.PAUSE
echo.EXIT
echo.
echo.:zipexists
echo.ECHO Error: %%targetzip%% already exists.  Delete it and re-try.
echo.PAUSE
echo.EXIT
echo.
echo.:zipaesexists
echo.ECHO Error: %%targetzipaes%% already exists.  Delete it and re-try.
echo.PAUSE
echo.EXIT
echo.
echo.:7zanotexist
echo.ECHO Error: %z7path% does not exist.
echo.PAUSE
echo.EXIT
echo.
echo.:opensslnotexist
echo.ECHO Error: %sslpath% does not exist.
echo.PAUSE
echo.EXIT)>pack7zAndEncrypt.cmd

:commonpart

(echo.@ECHO OFF
echo.rem  Based on Convenient Encryption by Scott D. Stoller
echo.rem  Adapted by MzY
echo.rem  This program is free software: you can redistribute it and/or modify
echo.rem  it under the terms of the GNU General Public License as published by
echo.rem  the Free Software Foundation, either version 3 of the License, or
echo.rem  [at your option] any later version.
echo.rem  This program is distributed in the hope that it will be useful,
echo.rem  but WITHOUT ANY WARRANTY; without even the implied warranty of
echo.rem  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
echo.rem  GNU General Public License for more details.
echo.rem  You should have received a copy of the GNU General Public License
echo.rem  along with this program.  If not, see http://www.gnu.org/licenses/.
echo.set target=%%~1
echo.set extension=%%target:~-3,3%%
echo.rem decrypted contains the name for the decrypted file.
echo.rem it is obtained from target by removing the last 4 characters
echo.set decrypted=%%target:~0,-4%%
echo.IF NOT %%extension%%==aes GOTO wrongextension
echo.IF EXIST "%%decrypted%%" GOTO fileexists
echo.IF NOT EXIST %sslpath% GOTO opensslnotexist
echo.%sslpath% enc -d -aes-256-cbc -in "%%target%%" -out "%%decrypted%%"
echo.PAUSE
echo.EXIT
echo.
echo.:wrongextension
echo.ECHO Error: target filename does not end with .aes
echo.PAUSE
echo.EXIT
echo.
echo.:fileexists
echo.echo Error: %%decrypted%% already exists.  Delete it and re-try.
echo.PAUSE
echo.EXIT
echo.
echo.:opensslnotexist
echo.ECHO Error: %sslpath% does not exist.
echo.PAUSE
echo.EXIT)>decrypt.cmd

(echo.@ECHO OFF
echo.rem  Based on Convenient Encryption by Scott D. Stoller
echo.rem  Adapted by MzY
echo.rem  This program is free software: you can redistribute it and/or modify
echo.rem  it under the terms of the GNU General Public License as published by
echo.rem  the Free Software Foundation, either version 3 of the License, or
echo.rem  [at your option] any later version.
echo.rem  This program is distributed in the hope that it will be useful,
echo.rem  but WITHOUT ANY WARRANTY; without even the implied warranty of
echo.rem  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
echo.rem  GNU General Public License for more details.
echo.rem  You should have received a copy of the GNU General Public License
echo.rem  along with this program.  If not, see http://www.gnu.org/licenses/.
echo.set target=%%~1
echo.IF EXIST "%%1.aes" goto fileexists
echo.IF NOT EXIST %sslpath% GOTO opensslnotexist
echo.%sslpath% enc -e -aes-256-cbc -in "%%target%%" -out "%%target%%.aes"
echo.PAUSE
echo.EXIT
echo.
echo.:fileexists
echo.ECHO Error: %%1.aes already exists.  Delete it and re-try.
echo.PAUSE
echo.EXIT
echo.
echo.:opensslnotexist
echo.ECHO Error: %sslpath% does not exist.
echo.PAUSE
echo.EXIT)>encrypt.cmd

(echo.Windows Registry Editor Version 5.00
echo.
echo.; Based on Convenient Encryption by Scott D. Stoller
echo.; Adapted by MzY
echo.; This program is free software: you can redistribute it and/or modify
echo.; it under the terms of the GNU General Public License as published by
echo.; the Free Software Foundation, either version 3 of the License, or
echo.; [at your option] any later version.
echo.; This program is distributed in the hope that it will be useful,
echo.; but WITHOUT ANY WARRANTY; without even the implied warranty of
echo.; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
echo.; GNU General Public License for more details.
echo.; You should have received a copy of the GNU General Public License
echo.; along with this program.  If not, see http://www.gnu.org/licenses/.
echo.
echo.[HKEY_CLASSES_ROOT\*\shell\Encrypt]
echo.
echo.[HKEY_CLASSES_ROOT\*\shell\Encrypt\command]
echo.@="%helperpath%encrypt.cmd \"%%1\""
echo.
echo.[HKEY_CLASSES_ROOT\*\shell\Decrypt]
echo.
echo.[HKEY_CLASSES_ROOT\*\shell\Decrypt\command]
echo.@="%helperpath%decrypt.cmd \"%%1\""
echo.
echo.%zipcomment:~1%[HKEY_CLASSES_ROOT\*\shell\Decrypt and Unzip]
echo.
echo.%zipcomment:~1%[HKEY_CLASSES_ROOT\*\shell\Decrypt and Unzip\command]
echo.%zipcomment:~1%@="%helperpath%decryptAndUnzip.cmd \"%%1\""
echo.
echo.%sevcomment:~1%[HKEY_CLASSES_ROOT\*\shell\Decrypt and Unpack]
echo.
echo.%sevcomment:~1%[HKEY_CLASSES_ROOT\*\shell\Decrypt and Unpack\command]
echo.%sevcomment:~1%@="%helperpath%decryptAndUnpack7z.cmd \"%%1\""
echo.
echo.%zipcomment:~1%[HKEY_CLASSES_ROOT\Directory\shell\Zip and Encrypt]
echo.
echo.%zipcomment:~1%[HKEY_CLASSES_ROOT\Directory\shell\Zip and Encrypt\command]
echo.%zipcomment:~1%@="%helperpath%zipAndEncrypt.cmd \"%%1\""
echo.
echo.%sevcomment:~1%[HKEY_CLASSES_ROOT\Directory\shell\Pack and Encrypt]
echo.
echo.%sevcomment:~1%[HKEY_CLASSES_ROOT\Directory\shell\Pack and Encrypt\command]
echo.%sevcomment:~1%@="%helperpath%pack7zAndEncrypt.cmd \"%%1\"")>install.reg

(echo.Windows Registry Editor Version 5.00
echo.
echo.; Based on Convenient Encryption by Scott D. Stoller
echo.; Adapted by MzY
echo.; This program is free software: you can redistribute it and/or modify
echo.; it under the terms of the GNU General Public License as published by
echo.; the Free Software Foundation, either version 3 of the License, or
echo.; [at your option] any later version.
echo.; This program is distributed in the hope that it will be useful,
echo.; but WITHOUT ANY WARRANTY; without even the implied warranty of
echo.; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
echo.; GNU General Public License for more details.
echo.; You should have received a copy of the GNU General Public License
echo.; along with this program.  If not, see http://www.gnu.org/licenses/.
echo.
echo.[-HKEY_CLASSES_ROOT\*\shell\Encrypt]
echo.
echo.[-HKEY_CLASSES_ROOT\*\shell\Encrypt\command]
echo.
echo.[-HKEY_CLASSES_ROOT\*\shell\Decrypt]
echo.
echo.[-HKEY_CLASSES_ROOT\*\shell\Decrypt\command]
echo.
echo.%zipcomment:~1%[-HKEY_CLASSES_ROOT\*\shell\Decrypt and Unzip]
echo.
echo.%zipcomment:~1%[-HKEY_CLASSES_ROOT\*\shell\Decrypt and Unzip\command]
echo.
echo.%sevcomment:~1%[-HKEY_CLASSES_ROOT\*\shell\Decrypt and Unpack]
echo.
echo.%sevcomment:~1%[-HKEY_CLASSES_ROOT\*\shell\Decrypt and Unpack\command]
echo.
echo.%zipcomment:~1%[-HKEY_CLASSES_ROOT\Directory\shell\Zip and Encrypt]
echo.
echo.%zipcomment:~1%[-HKEY_CLASSES_ROOT\Directory\shell\Zip and Encrypt\command]
echo.
echo.%sevcomment:~1%[-HKEY_CLASSES_ROOT\Directory\shell\Pack and Encrypt]
echo.
echo.%sevcomment:~1%[-HKEY_CLASSES_ROOT\Directory\shell\Pack and Encrypt\command])>uninstall.reg



Ярлыки:

Комментарии

Отправить комментарий

Популярные сообщения из этого блога

Печать файлов из папки в автоматическом режиме

Простой метод организовать простой "сервер печати" без драйверов.
Отправить комментарий
Далее...

Как убрать рекламные баннеры Розетки

С некоторых пор Adblock оказался бессилен заблокировать баннеры Розетки, которые теперь бессовестно прут из всех щелей, порой даже ломая разметку страницы.
2 комментария
Далее...